codigo-base.el-foro.net
Would you like to react to this message? Create an account in a few clicks or log in to continue.
CHAT
Search
 
 

Display results as :
 


Rechercher Advanced Search

Latest topics
» Saludos Andres Reyes - MURIO ESTE FORO.?
Ribbon + tExplorer Bar EmptyThu Oct 26, 2017 8:01 pm by joseluisysturiz

» Eliminar TaskGroup y Crear Uno nuevo en su misma ubicación
Ribbon + tExplorer Bar EmptyWed Jun 27, 2012 3:09 pm by hjvargas

» ERROR AL EJECUTAR DEMO DE TTPANEL
Ribbon + tExplorer Bar EmptyWed Oct 26, 2011 4:46 pm by Fidel Echavarrria

» ERROR AL COMPILAR MI SISTEMA TTASKPANEL.LIB|c_dibbmp
Ribbon + tExplorer Bar EmptyWed Oct 26, 2011 3:42 pm by Andres Reyes

» Hola a todos
Ribbon + tExplorer Bar EmptyWed Apr 27, 2011 12:44 am by Pedro

» Los saludos de un profesor de Ingles en Costa Rica soleada.
Ribbon + tExplorer Bar EmptyWed Jan 26, 2011 4:03 pm by RichardBlank

» Con OutLook2003
Ribbon + tExplorer Bar EmptyTue Jan 11, 2011 7:38 pm by Francis Barrimbhal

» Una sugerencia en cuanto a la distribución de la Lib
Ribbon + tExplorer Bar EmptyTue Jan 11, 2011 7:25 pm by Francis Barrimbhal

» problema con la animación
Ribbon + tExplorer Bar EmptyMon Aug 30, 2010 4:35 pm by armando.lagunas


Ribbon + tExplorer Bar

2 posters

Go down

Ribbon + tExplorer Bar Empty Ribbon + tExplorer Bar

Post  patricio avalos aguirre Tue Jul 06, 2010 10:35 am

Hola Andres

Felicitaciones por esta nueva clase..

Mi consulta es como poder hacer de una opcion del ribbon
una ventana window con taskbar + xbrowse


saludos
Patricio Avalos A.



patricio avalos aguirre
patricio avalos aguirre

Posts : 9
Reputation : 0
Join date : 2010-07-06
Age : 54
Location : la serena

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  Andres Reyes Tue Jul 06, 2010 3:05 pm

Hola Patricio,

No entendi muy bien tu pregunta no se si te refieres que al hacer click en alguna opcion del ribbon se muestre una nueva ventana con un ttaskpanel + xbarowse sin que sea MDI,

Seria en un Dialog ??

o En Una Ventana Normal ??

Aqui te dejo un ejemplo muy sencillo como seria en una ventana normal.

Code:



#include "fivewin.ch"
#include "taskpanel.ch"
#include "ribbon.ch"


PROCEDURE MAIN()

  LOCAL oWnd, oTaskPanel
  LOCAL oRBar, oGr, oBtn1

  //Definimos la Ventana Principal
  DEFINE WINDOW oWnd                    ;
        FROM 1, 1  TO 600, 600 PIXEL    ;
        TITLE "TTaskPanel 1.0"        ;
        COLOR CLR_WHITE, CLR_GRAY  ;
        ICON "#1"

  DEFINE RIBBONBAR oRBar WINDOW oWnd PROMPT "Configuración", "Ficheros", "Informes", "Ayudas" HEIGHT 133 TOPMARGIN 25

  oRBar:nLeftMargin = 75
  oRBar:CalcPos()

  ADD GROUP oGr RIBBON oRBar TO OPTION 1 PROMPT "Test" width 130

  @ 2,5 ADD BUTTON oBtn1 PROMPT "Test" GROUP oGr ACTION ( BrowseTest() ) ;
  ROUND SIZE 50,65


  ACTIVATE WINDOW oWnd

  RETURN

FUNCTION BrowseTest()

  LOCAL oWnd, oBrw, oTaskPanel, aArray

  DEFINE WINDOW oWnd TITLE "Taskpanel & Browse" FROM 10, 10 TO 650, 800 PIXEL
  oWnd:Hide()
      DEFINE TASKPANEL oTaskPanel ANCHOR LEFT
        TASKGROUP "Tareas de Video" BITMAP "HEADER1" SPECIAL WATERMARK "WATERMARK"
            TASKITEM "Reproducir todo" BITMAP "ICON1" TOOLTIP "Tooltip de Prueba 1"
            TASKITEM "Obtener Imagenes desde una camara o un escaner" BITMAP "ICON2"
            TASKITEM "Copiar todos los elementos a un CD" BITMAP "ICON3"
        ENDTASKGROUP
        TASKGROUP "Tareas de archivo y carpeta sa"
            TASKITEM "Cambiar nombre a este archivo" BITMAP "ICON4"
            TASKITEM "Mover este archivo" BITMAP "ICON5"
            TASKITEM "Copiar este archivo" BITMAP "ICON6"
            TASKITEM "Publicar este archivo en web" BITMAP "ICON7"
            TASKITEM "Enviar este archivo por correo electronico" BITMAP "ICON8"
            TASKITEM "Eliminar este archivo" BITMAP "ICON9"
        ENDTASKGROUP
        TASKGROUP  "Otros sitios"
            TASKITEM "Mi PC" BITMAP "ICON10"
            TASKITEM "Mis sitios de red" BITMAP "ICON11"
        ENDTASKGROUP
        TASKGROUP  "Detalles" NO COLLAPSABLE
            TASKITEM "<b>TTaskPanel()</b>" + ;
                    "<p>Clase para la creacion de paneles de tareas</p>"+;
                    "<p><b>Autor</b></p>" +;
                    "<p>Andres Reyes Hernandez</p>" INFO
        ENDTASKGROUP
      ENDTASKPANEL

      aArray := {}
      aAdd( aArray , { "Juan Domingo Lopez Aramburo", "Rio Panuco #454645", "6699843023"} )
      aAdd( aArray , { "Mario Rosales Montevideo", "Rio Presidio #546564", "6699879788"} )
      aAdd( aArray , { "Felipe de Jesus Ramirez Lopez", "Rio de la Loma #18795", "6695644556"} )
      aAdd( aArray , { "Renesio Recto", "Rio Florido #56546", "6699565464"} )

      oBrw := TXBrowse():New( oWnd )

      oBrw:SetArray( aArray )

      oBrw:aCols[1]:cHeader := "Nombre"
      oBrw:aCols[2]:cHeader := "Direccion"
      oBrw:aCols[3]:cHeader := "Telefono"

      oBrw:CreateFromCode()

      oWnd:oClient := oBrw
      oWnd:Resize()

  ACTIVATE WINDOW oWnd

  RETURN Nil
Andres Reyes
Andres Reyes
Admin

Posts : 38
Reputation : 3
Join date : 2010-06-23
Age : 44
Location : Mazatlan, Sinaloa, Mexico

http://codigo-base.blogspot.com

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  patricio avalos aguirre Tue Jul 06, 2010 3:27 pm

Gracias por responder

lo que quiero es que quede la ventana debajo del ribon, maximizada pero
no quiero que en el ribbon salgan los menus de archivo,etc..

le coloco todas las forma
Code:

FUNCTION BrowseTest( oRibon )

  LOCAL oWnd, oBrw, oTaskPanel, aArray

  DEFINE WINDOW oWnd TITLE "Taskpanel & Browse" FROM 10, 10 TO 650, 800 PIXEL OF oRibon
  oWnd:Hide()


Code:

FUNCTION BrowseTest( oWinPrincipal )

  LOCAL oWnd, oBrw, oTaskPanel, aArray

  DEFINE WINDOW oWnd TITLE "Taskpanel & Browse" FROM 10, 10 TO 650, 800 PIXEL OF oWinPrincipal
  oWnd:Hide()


no me cuadran con le ribbon

desde ya gracias

Ribbon + tExplorer Bar Ribon

ImageShack.us

patricio avalos aguirre
patricio avalos aguirre

Posts : 9
Reputation : 0
Join date : 2010-07-06
Age : 54
Location : la serena

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  Andres Reyes Tue Jul 06, 2010 4:00 pm

Esta es otra opción sin usar MDI,


Code:

#include "fivewin.ch"
#include "taskpanel.ch"
#include "ribbon.ch"

PROCEDURE MAIN()

  LOCAL oWnd, oTaskPanel
  LOCAL oRBar, oGr, oBtn1, oBtn2, oPanel

  //Definimos la Ventana Principal
  DEFINE WINDOW oWnd                    ;
        FROM 1, 1  TO 600, 600 PIXEL    ;
        TITLE "TTaskPanel 1.0"        ;
        COLOR CLR_WHITE, CLR_GRAY  ;
        ICON "#1"

  DEFINE RIBBONBAR oRBar WINDOW oWnd PROMPT "Configuración", "Ficheros", "Informes", "Ayudas" HEIGHT 133 TOPMARGIN 25

  oRBar:nLeftMargin = 75
  oRBar:CalcPos()

  ADD GROUP oGr RIBBON oRBar TO OPTION 1 PROMPT "Test" width 130

  @ 2,5 ADD BUTTON oBtn1 PROMPT "Mostrar" GROUP oGr ACTION ( oPanel:Show() ) ;
  ROUND SIZE 50,65

  @ 2,75 ADD BUTTON oBtn2 PROMPT "Ocultar" GROUP oGr ACTION ( oPanel:Hide() ) ;
  ROUND SIZE 50,65

  oPanel := TPanel():New(,,,, oWnd)
  oPanel:Hide()

  BrowseTest( oPanel )

  oWnd:oClient := oPanel
  oWnd:Resize()

  ACTIVATE WINDOW oWnd

  RETURN

FUNCTION BrowseTest( oPanel )

  LOCAL oBrw, oTaskPanel, aArray

      DEFINE TASKPANEL oTaskPanel OF oPanel ANCHOR LEFT
        TASKGROUP "Tareas de Video" BITMAP "HEADER1" SPECIAL WATERMARK "WATERMARK"
            TASKITEM "Reproducir todo" BITMAP "ICON1" TOOLTIP "Tooltip de Prueba 1"
            TASKITEM "Obtener Imagenes desde una camara o un escaner" BITMAP "ICON2"
            TASKITEM "Copiar todos los elementos a un CD" BITMAP "ICON3"
        ENDTASKGROUP
        TASKGROUP "Tareas de archivo y carpeta sa"
            TASKITEM "Cambiar nombre a este archivo" BITMAP "ICON4"
            TASKITEM "Mover este archivo" BITMAP "ICON5"
            TASKITEM "Copiar este archivo" BITMAP "ICON6"
            TASKITEM "Publicar este archivo en web" BITMAP "ICON7"
            TASKITEM "Enviar este archivo por correo electronico" BITMAP "ICON8"
            TASKITEM "Eliminar este archivo" BITMAP "ICON9"
        ENDTASKGROUP
        TASKGROUP  "Otros sitios"
            TASKITEM "Mi PC" BITMAP "ICON10"
            TASKITEM "Mis sitios de red" BITMAP "ICON11"
        ENDTASKGROUP
        TASKGROUP  "Detalles" NO COLLAPSABLE
            TASKITEM "<b>TTaskPanel()</b>" + ;
                    "<p>Clase para la creacion de paneles de tareas</p>"+;
                    "<p><b>Autor</b></p>" +;
                    "<p>Andres Reyes Hernandez</p>" INFO
        ENDTASKGROUP
      ENDTASKPANEL

      aArray := {}
      aAdd( aArray , { "Juan Domingo Lopez Aramburo", "Rio Panuco #454645", "6699843023"} )
      aAdd( aArray , { "Mario Rosales Montevideo", "Rio Presidio #546564", "6699879788"} )
      aAdd( aArray , { "Felipe de Jesus Ramirez Lopez", "Rio de la Loma #18795", "6695644556"} )
      aAdd( aArray , { "Renesio Recto", "Rio Florido #56546", "6699565464"} )

      oBrw := TXBrowse():New( oPanel )

      oBrw:SetArray( aArray )

      oBrw:aCols[1]:cHeader := "Nombre"
      oBrw:aCols[2]:cHeader := "Direccion"
      oBrw:aCols[3]:cHeader := "Telefono"

      oBrw:CreateFromCode()

      oPanel:oClient := oBrw
      oPanel:Resize()

  RETURN Nil

//----------------------------------------------------------------------------//


Saludos,

Andres Reyes
Andres Reyes
Andres Reyes
Admin

Posts : 38
Reputation : 3
Join date : 2010-06-23
Age : 44
Location : Mazatlan, Sinaloa, Mexico

http://codigo-base.blogspot.com

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  patricio avalos aguirre Tue Jul 06, 2010 4:05 pm

Excelente

ahora ha entender como funciona

gracias..

saludos
Patricio Avalos
patricio avalos aguirre
patricio avalos aguirre

Posts : 9
Reputation : 0
Join date : 2010-07-06
Age : 54
Location : la serena

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  patricio avalos aguirre Tue Jul 06, 2010 4:14 pm

Nuevamente

Solo consulta

revisando el codigo me encuentro que ocultas y muestras ahora yo requiero ir cambiando las opciones del
panel tastbar segun la opcion que se presione en el ribon y las de xbrowse

se puede reutilizar el mismo panel o hay que colocar tantos paneles segun las opciones?


patricio avalos aguirre
patricio avalos aguirre

Posts : 9
Reputation : 0
Join date : 2010-07-06
Age : 54
Location : la serena

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  Andres Reyes Tue Jul 06, 2010 5:13 pm

Se puede reutilizar el mismo TTaskPanel,

Code:



#include "fivewin.ch"
#include "taskpanel.ch"
#include "ribbon.ch"


PROCEDURE MAIN()

  LOCAL oWnd, oTaskPanel
  LOCAL oRBar, oGr, oBtn1, oBtn2, oBtn3, oPanel

  //Definimos la Ventana Principal
  DEFINE WINDOW oWnd                    ;
        FROM 1, 1  TO 600, 600 PIXEL    ;
        TITLE "TTaskPanel 1.0"        ;
        COLOR CLR_WHITE, CLR_GRAY  ;
        ICON "#1"

  DEFINE RIBBONBAR oRBar WINDOW oWnd PROMPT "Configuración", "Ficheros", "Informes", "Ayudas" HEIGHT 133 TOPMARGIN 25

  oRBar:nLeftMargin = 75
  oRBar:CalcPos()

  ADD GROUP oGr RIBBON oRBar TO OPTION 1 PROMPT "Test" width 200

  @ 2,5 ADD BUTTON oBtn1 PROMPT "Opcion #1" GROUP oGr ACTION ( SetOption1( oPanel ) );
  ROUND SIZE 60,65

  @ 2,70 ADD BUTTON oBtn1 PROMPT "Opcion #2" GROUP oGr ACTION ( SetOption2( oPanel ) ) ;
  ROUND SIZE 60,65

  @ 2,135 ADD BUTTON oBtn3 PROMPT "Ocultar" GROUP oGr ACTION ( oPanel:Hide() ) ;
  ROUND SIZE 60,65

  oPanel := TPanel():New(,,,, oWnd)
  oPanel:Hide()

  BrowseTest( oPanel )

  oWnd:oClient := oPanel
  oWnd:Resize()

  ACTIVATE WINDOW oWnd

  RETURN

FUNCTION BrowseTest( oPanel )

  LOCAL oBrw, oTaskPanel, aArray

      DEFINE TASKPANEL oTaskPanel OF oPanel ANCHOR LEFT
        TASKGROUP "Tareas de Video" BITMAP "HEADER1" SPECIAL WATERMARK "WATERMARK"
            TASKITEM "Reproducir todo" BITMAP "ICON1" TOOLTIP "Tooltip de Prueba 1"
            TASKITEM "Obtener Imagenes desde una camara o un escaner" BITMAP "ICON2"
            TASKITEM "Copiar todos los elementos a un CD" BITMAP "ICON3"
        ENDTASKGROUP
        TASKGROUP "Tareas de archivo y carpeta sa"
            TASKITEM "Cambiar nombre a este archivo" BITMAP "ICON4"
            TASKITEM "Mover este archivo" BITMAP "ICON5"
            TASKITEM "Copiar este archivo" BITMAP "ICON6"
            TASKITEM "Publicar este archivo en web" BITMAP "ICON7"
            TASKITEM "Enviar este archivo por correo electronico" BITMAP "ICON8"
            TASKITEM "Eliminar este archivo" BITMAP "ICON9"
        ENDTASKGROUP
        TASKGROUP  "Otros sitios"
            TASKITEM "Mi PC" BITMAP "ICON10"
            TASKITEM "Mis sitios de red" BITMAP "ICON11"
        ENDTASKGROUP
        TASKGROUP  "Detalles" NO COLLAPSABLE
            TASKITEM "<b>TTaskPanel()</b>" + ;
                    "<p>Clase para la creacion de paneles de tareas</p>"+;
                    "<p><b>Autor</b></p>" +;
                    "<p>Andres Reyes Hernandez</p>" INFO
        ENDTASKGROUP
      ENDTASKPANEL

      aArray := {}
      aAdd( aArray , { "Juan Domingo Lopez Aramburo", "Rio Panuco #454645", "6699843023"} )
      aAdd( aArray , { "Mario Rosales Montevideo", "Rio Presidio #546564", "6699879788"} )
      aAdd( aArray , { "Felipe de Jesus Ramirez Lopez", "Rio de la Loma #18795", "6695644556"} )
      aAdd( aArray , { "Renesio Recto", "Rio Florido #56546", "6699565464"} )

      oBrw := TXBrowse():New( oPanel )

      oBrw:SetArray( aArray )

      oBrw:aCols[1]:cHeader := "Nombre"
      oBrw:aCols[2]:cHeader := "Direccion"
      oBrw:aCols[3]:cHeader := "Telefono"

      oBrw:CreateFromCode()

      oPanel:oClient := oBrw
      oPanel:Resize()

  RETURN Nil

FUNCTION SetOption1( oPanel )
  LOCAL oTaskPanel := oPanel:oLeft

  oTaskPanel:SuspendLayout()
  oTaskPanel:Item(1):Show()
  oTaskPanel:Item(2):Hide()
  oTaskPanel:Item(3):Item(1):Show()
  oTaskPanel:Item(3):Item(2):Hide()
  oTaskPanel:EndLayout()

  oPanel:Show()

  RETURN Nil

FUNCTION SetOption2( oPanel )
  LOCAL oTaskPanel := oPanel:oLeft

  oTaskPanel:SuspendLayout()
  oTaskPanel:Item(1):Hide()
  oTaskPanel:Item(2):Show()
  oTaskPanel:Item(3):Item(1):Hide()
  oTaskPanel:Item(3):Item(2):Show()
  oTaskPanel:EndLayout()


  oPanel:Show()
  RETURN Nil

//----------------------------------------------------------------------------//
Andres Reyes
Andres Reyes
Admin

Posts : 38
Reputation : 3
Join date : 2010-06-23
Age : 44
Location : Mazatlan, Sinaloa, Mexico

http://codigo-base.blogspot.com

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  patricio avalos aguirre Wed Jul 07, 2010 7:22 am

Excelente

muchas gracias

saludos
Patricio

pd: Recuerdo la excelente libreria WDEBUG, como va ese proyecto?



patricio avalos aguirre
patricio avalos aguirre

Posts : 9
Reputation : 0
Join date : 2010-07-06
Age : 54
Location : la serena

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  Andres Reyes Wed Jul 07, 2010 7:59 am

Gracias a dios, esas fuentes todavía las tengo por aquí, espero pronto poder dedicarle un poco de tiempo a esa librería,

Saludos,

Andres Reyes
Andres Reyes
Andres Reyes
Admin

Posts : 38
Reputation : 3
Join date : 2010-06-23
Age : 44
Location : Mazatlan, Sinaloa, Mexico

http://codigo-base.blogspot.com

Back to top Go down

Ribbon + tExplorer Bar Empty Re: Ribbon + tExplorer Bar

Post  Sponsored content


Sponsored content


Back to top Go down

Back to top


 
Permissions in this forum:
You cannot reply to topics in this forum